Cerere Plugin

Sa[q] · Posted: 01-08-2015, 16:48:06 | Translate post to: ... (Click for more languages)

Salut. As vrea si eu un plugin cu arme V.I.P pe flagul "P" si sa aibe urmatoarele arme.
Ak47+Deagle Gold
M4+Deagle Gold
AWP+Deagle Gold
P90+Deagle Gold.
Sa fie doar pt cei care au VIP si sa fie roate armele gold.
PS: Imi trebuie si Models

Sa[q] · Posted: 02-08-2015, 11:33:35 | Translate post to: ... (Click for more languages)

Cineva?

destroi112 · Posted: 02-08-2015, 14:26:43 | Translate post to: ... (Click for more languages)

Ai rabdare daca are cineva modelele sa le puna aici sa imi fie mai usor .
PS:Ak47Gold e si pentru playeri nu cred ca mai are sens sa o pui si la VIP shotgunul ar merge in loc.Astept modelele(am net-ul mai prost si stau mult pana le gasesc.)

Retired from Amxmodx

Sa[q] · Posted: 02-08-2015, 14:44:46 | Translate post to: ... (Click for more languages)

Ak la playeri e vu bani si sa o cumperi bu e bine. Pune in loc de P90 shotgun+ Deagle Gold.

Posturi unite automat, 02-08-2015, 15:44:46

Poftik Models: http://cs.gamebanana.com/skins/download/120145

destroi112 · Posted: 04-08-2015, 18:51:28 | Translate post to: ... (Click for more languages)

Mai ai nevoie de el sa stiu daca il fac ?

Retired from Amxmodx

YONTU · Posted: 05-08-2015, 13:11:17 | Translate post to: ... (Click for more languages)

Destroy, se vede ca postezi pentru +1. Jalnic.
Poftim pluginul:

Spoiler:

Code:

#include <amxmodx>
#include <amxmisc>
#include <hamsandwich>
#include <fakemeta>
#include <cstrike>
#include <engine>
#include <fun>
#include <xs>

new const PLUGIN_NAME[] = "VIP Gold",
PLUGIN_VERSION[] = "1.0",
PLUGIN_AUTHOR[] = "YONTU";

#define count 4       // de cate ori poti accesa meniul pe runda
new const tag[] = "[VIP GOLD]";    // tagul care apara in chat (prefix)
new const contact[] = "[email protected]"; // cei care nu au vip, le va aparea un mesaj informativ cum pot achizitiona VIP

enum
{
SECTION_NONE = 0,
SECTION_GOLDENAK47,
SECTION_GOLDENM4A1,
SECTION_GOLDENAWP,
SECTION_GOLDENM3,
SECTION_GOLDENMP5
}

enum (+= 100)
{
GOLDENAK47_WEAPONKEY = 1244,
GOLDENM4A1_WEAPONKEY,
GOLDENAWP_WEAPONKEY,
GOLDENM3_WEAPONKEY,
GOLDENMP5NAVY_WEAPONKEY
}

enum _:g_weapons
{
AK47 = 0,
M4A1,
AWP,
M3,
MP5NAVY
}

enum _:g_model
{
V_MODEL[64],
P_MODEL[64],
W_MODEL[64]
}

#define is_user_valid(%1) (1 <= %1 <= max_players)
#define DMG_HEGRENADE (1<<24)
#define EV_INT_WEAPONKEY EV_INT_impulse
#define ENG_NULLENT    -1

new g_HostName[64], cvar_hostname, max_players;
new menu, menu_callback, text_menu[128], text_items[5][128];
new g_Golden[g_weapons][33], g_Gold[g_weapons][g_model], g_GoldenZoom[5][33], SpriteTexture, g_bullets[33];
new WpnName[32], Float:cl_pushangle[33][3];

const NORECOIL_WPN_BS = ((1<<2) | (1<<CSW_HEGRENADE) | (1<<CSW_SMOKEGRENADE) | (1<<CSW_FLASHBANG) | (1<<CSW_KNIFE) | (1<<CSW_C4));

new const weapons_name[][] =
{
"weapon_ak47",
"weapon_m4a1",
"weapon_awp",
"weapon_m3",
"weapon_mp5navy"
}

new count_vm[33];
new Float:multi_dmg[5], Float:no_recoil[5], Float:throw_speed[5], unlimited_clip[g_weapons], gold_bullets[g_weapons], on[g_weapons], zoom[g_weapons];

#define is_user_vip(%1) (get_user_flags(%1) & ADMIN_LEVEL_D)

public plugin_init()
{
register_plugin(PLUGIN_NAME, PLUGIN_VERSION, PLUGIN_AUTHOR);
register_cvar("universal_vip", PLUGIN_VERSION, FCVAR_SPONLY|FCVAR_SERVER);
set_cvar_string("universal_vip", PLUGIN_VERSION);

register_logevent("logevent_RoundStart", 2, "1=Round_Start");
register_event("CurWeapon", "event_CurWeapon", "be", "1=1");
register_event("CurWeapon", "event_GoldBullets", "be", "1=1", "3>0");

RegisterHam(Ham_TakeDamage, "player", "fw_TakeDamage");
new i;
for(i = 0; i < sizeof weapons_name; i++)
   RegisterHam(Ham_Item_AddToPlayer, weapons_name[i], "fw_AddToPlayer");
for(i = 1; i <= CSW_P90; i++)
{
   if(!(NORECOIL_WPN_BS & (1<<i)) && get_weaponname(i, WpnName, charsmax(WpnName)))
   {
      RegisterHam(Ham_Weapon_PrimaryAttack, WpnName, "fw_PrimaryAttack");
      RegisterHam(Ham_Weapon_PrimaryAttack, WpnName, "fw_PrimaryAttackPost", 1);
   }
}

register_forward(FM_SetModel, "fw_SetModel");
register_forward(FM_CmdStart, "fw_CmdStart");

register_clcmd("say vipgold", "ShowVipMenu");
register_clcmd("say_team vipgold", "ShowVipMenu");
register_clcmd("say /vipgold", "ShowVipMenu");
register_clcmd("say_team /vipgold", "ShowVipMenu");

max_players = get_maxplayers();
cvar_hostname = get_cvar_pointer("hostname");
}

public plugin_precache()
{
load_customization_from_files();

SpriteTexture = precache_model("sprites/dot.spr");
precache_sound("weapons/zoom.wav");
}

public plugin_cfg()
{
get_pcvar_string(cvar_hostname, g_HostName, charsmax(g_HostName));
}

public client_putinserver(id)
{
if(is_user_vip(id))
{
   new i;
   for(i = 0; i < 5; i++)
      g_Golden[i][id] = 0;
}
}

public logevent_RoundStart()
{
new players[32], num, i;
get_players(players, num, "ach");

for(i = 0; i < num; i++)
{
   if(!is_user_vip(players[i])) continue;

   arrayset(count_vm, 0, 33);
   arrayset(g_Golden[AK47], 0, 33);
   arrayset(g_Golden[M4A1], 0, 33);
   arrayset(g_Golden[AWP], 0, 33);
   arrayset(g_Golden[M3], 0, 33);
   arrayset(g_Golden[MP5NAVY], 0, 33);
   arrayset(g_GoldenZoom[AK47], 0, 33);
   arrayset(g_GoldenZoom[M4A1], 0, 33);
   arrayset(g_GoldenZoom[AWP], 0, 33);
   arrayset(g_GoldenZoom[M3], 0, 33);
   arrayset(g_GoldenZoom[MP5NAVY], 0, 33);
}
}

public event_CurWeapon(id)
{
if(!is_user_alive(id))
   return PLUGIN_HANDLED;

if(!is_user_vip(id))
   return PLUGIN_HANDLED;

new weaponid = read_data(2);
new ent;

switch(weaponid)
{
   case CSW_AK47:
   {
      if(!g_Golden[AK47][id])
         return PLUGIN_CONTINUE;

      set_pev(id, pev_viewmodel2, g_Gold[AK47][V_MODEL]);
      set_pev(id, pev_weaponmodel2, g_Gold[AK47][P_MODEL]);

      if(unlimited_clip[AK47])
         set_pdata_int(get_pdata_cbase(id, 373), 51, 30, 4);

      ent = fm_find_ent_by_owner(-1, weapons_name[AK47], id);
   }
   case CSW_M4A1:
   {
      if(!g_Golden[M4A1][id])
         return PLUGIN_CONTINUE;

      set_pev(id, pev_viewmodel2, g_Gold[M4A1][V_MODEL]);
      set_pev(id, pev_weaponmodel2, g_Gold[M4A1][P_MODEL]);

      if(unlimited_clip[M4A1])
         set_pdata_int(get_pdata_cbase(id, 373), 51, 30, 4);

      ent = fm_find_ent_by_owner(-1, weapons_name[M4A1], id);
   }
   case CSW_AWP:
   {
      if(!g_Golden[AWP][id])
         return PLUGIN_CONTINUE;

      set_pev(id, pev_viewmodel2, g_Gold[AWP][V_MODEL]);
      set_pev(id, pev_weaponmodel2, g_Gold[AWP][P_MODEL]);

      if(unlimited_clip[AWP])
         set_pdata_int(get_pdata_cbase(id, 373), 51, 10, 4);

      ent = fm_find_ent_by_owner(-1, weapons_name[AWP], id);
   }
   case CSW_M3:
   {
      if(!g_Golden[M3][id])
         return PLUGIN_CONTINUE;

      set_pev(id, pev_viewmodel2, g_Gold[M3][V_MODEL]);
      set_pev(id, pev_weaponmodel2, g_Gold[M3][P_MODEL]);

      if(unlimited_clip[M3])
         set_pdata_int(get_pdata_cbase(id, 373), 51, 8, 4);

      ent = fm_find_ent_by_owner(-1, weapons_name[M3], id);
   }
   case CSW_MP5NAVY:
   {
      if(!g_Golden[MP5NAVY][id])
         return PLUGIN_CONTINUE;

      set_pev(id, pev_viewmodel2, g_Gold[MP5NAVY][V_MODEL]);
      set_pev(id, pev_weaponmodel2, g_Gold[MP5NAVY][P_MODEL]);

      if(unlimited_clip[MP5NAVY])
         set_pdata_int(get_pdata_cbase(id, 373), 51, 30, 4);

      ent = fm_find_ent_by_owner(-1, weapons_name[MP5NAVY], id);
   }
   default: return PLUGIN_CONTINUE;
}

new Float:N_Speed = CheckVipWeapons(id, 2);
if(ent)
{
   static Float:Delay, Float:M_Delay;
   Delay = get_pdata_float(ent, 46, 4) * N_Speed;
   M_Delay = get_pdata_float(ent, 47, 4) * N_Speed;

   if(Delay > 0.0)
   {
      set_pdata_float(ent, 46, Delay, 4);
      set_pdata_float(ent, 47, M_Delay, 4);
   }
}

return PLUGIN_CONTINUE;
}

public event_GoldBullets(id)
{
new clip;
new weaponid = get_user_weapon(id, clip);

if(!is_user_alive(id) && !is_user_vip(id))
   return PLUGIN_HANDLED;

if(g_bullets[id] > clip)
{
   if(
   ((weaponid == CSW_AK47 && g_Golden[AK47][id]) && gold_bullets[AK47] == 1) ||
   ((weaponid == CSW_M4A1 && g_Golden[M4A1][id]) && gold_bullets[M4A1] == 1) ||
   ((weaponid == CSW_AWP && g_Golden[AWP][id]) && gold_bullets[AWP] == 1) ||
   ((weaponid == CSW_M3 && g_Golden[M3][id]) && gold_bullets[M3] == 1) ||
   ((weaponid == CSW_MP5NAVY && g_Golden[MP5NAVY][id]) && gold_bullets[MP5NAVY] == 1))
   {
      new vec[2][3];
      get_user_origin(id, vec[0], 1); // origin; your camera point.
      get_user_origin(id, vec[1], 4); // termina; where your bullet goes (4 is cs-only)

      message_begin(MSG_BROADCAST, SVC_TEMPENTITY);
      write_byte(0); //TE_BEAMENTPOINTS 0
      write_coord(vec[0][0]);
      write_coord(vec[0][1]);
      write_coord(vec[0][2]);
      write_coord(vec[1][0]);
      write_coord(vec[1][1]);
      write_coord(vec[1][2]);
      write_short(SpriteTexture);
      write_byte(1); // framestart
      write_byte(5); // framerate
      write_byte(2); // life
      write_byte(10); // width
      write_byte(0); // noise
      write_byte(255); // red
      write_byte(215); // green
      write_byte(0); // blue
      write_byte(200); // brightness
      write_byte(150); // speed
      message_end();
   }
   return PLUGIN_CONTINUE;
}

g_bullets[id] = clip;
return PLUGIN_HANDLED;
}

public fw_TakeDamage(victim, inflictor, attacker, Float:fDamage, iDmgType)
{
if(is_user_valid(attacker) && is_user_alive(attacker) && is_user_vip(attacker) && victim != attacker)
{
   if(iDmgType & DMG_HEGRENADE)
      return HAM_IGNORED;

   fDamage *= CheckVipWeapons(attacker, 0);

   SetHamParamFloat(4, fDamage);
   return HAM_HANDLED;
}
return HAM_IGNORED;
}

public fw_AddToPlayer(ent, id)
{
if(is_valid_ent(ent) && is_user_vip(id) && is_user_connected(id))
{
   switch(entity_get_int(ent, EV_INT_WEAPONKEY))
   {
      case GOLDENAK47_WEAPONKEY:
      {
         g_Golden[AK47][id] = 1;
         entity_set_int(ent, EV_INT_WEAPONKEY, 0);
      }
      case GOLDENM4A1_WEAPONKEY:
      {
         g_Golden[M4A1][id] = 1;
         entity_set_int(ent, EV_INT_WEAPONKEY, 0);
      }
      case GOLDENAWP_WEAPONKEY:
      {
         g_Golden[AWP][id] = 1;
         entity_set_int(ent, EV_INT_WEAPONKEY, 0);
      }
      case GOLDENM3_WEAPONKEY:
      {
         g_Golden[M3][id] = 1;
         entity_set_int(ent, EV_INT_WEAPONKEY, 0);
      }
      case GOLDENMP5NAVY_WEAPONKEY:
      {
         g_Golden[MP5NAVY][id] = 1;
         entity_set_int(ent, EV_INT_WEAPONKEY, 0);
      }
   }
   return HAM_HANDLED;
}

return HAM_IGNORED;
}

public fw_PrimaryAttack(ent)
{
new id = pev(ent, pev_owner);
if(is_user_alive(id) && is_user_vip(id))
   pev(id, pev_punchangle, cl_pushangle[id]);

return HAM_IGNORED;
}

public fw_PrimaryAttackPost(ent)
{
new id = pev(ent, pev_owner);
if(is_user_alive(id) && is_user_vip(id))
{
   new Float:fPush[3], Float:fRecoil;
   pev(id, pev_punchangle, fPush);
   fRecoil = CheckVipWeapons(id, 1);

   xs_vec_sub(fPush, cl_pushangle[id], fPush);
   xs_vec_mul_scalar(fPush, fRecoil, fPush);
   xs_vec_add(fPush, cl_pushangle[id], fPush);

   set_pev(id, pev_punchangle, fPush);
}

return HAM_IGNORED;
}

public fw_SetModel(entity, model[])
{
if(!is_valid_ent(entity))
   return FMRES_IGNORED;

static szClassName[33];
entity_get_string(entity, EV_SZ_classname, szClassName, charsmax(szClassName));

if(!equal(szClassName, "weaponbox"))
   return FMRES_IGNORED;

static iOwner, iStored;
iOwner = entity_get_edict(entity, EV_ENT_owner);

if(!is_user_vip(iOwner))
   return FMRES_IGNORED;

switch(model[9])
{
   case 'a':
   {
      switch(model[10])
      {
         case 'k':
         {
            iStored = fm_find_ent_by_owner(ENG_NULLENT, weapons_name[AK47], entity);

            if(g_Golden[AK47][iOwner] == 1 && is_valid_ent(iStored))
            {
               entity_set_int(iStored, EV_INT_WEAPONKEY, GOLDENAK47_WEAPONKEY);
               g_Golden[AK47][iOwner] = 0;
               entity_set_model(entity, g_Gold[AK47][W_MODEL]);

               return FMRES_SUPERCEDE;
            }
         }
         case 'w':
         {
            iStored = fm_find_ent_by_owner(ENG_NULLENT, weapons_name[AWP], entity);

            if(g_Golden[AWP][iOwner] == 1 && is_valid_ent(iStored))
            {
               entity_set_int(iStored, EV_INT_WEAPONKEY, GOLDENAWP_WEAPONKEY);

               g_Golden[AWP][iOwner] = 0;
               entity_set_model(entity, g_Gold[AWP][W_MODEL]);

               return FMRES_SUPERCEDE;
            }
         }
      }
   }
   case 'm':
   {
      switch(model[10])
      {
         case '3':
         {
            iStored = fm_find_ent_by_owner(ENG_NULLENT, weapons_name[M3], entity);

            if(g_Golden[M3][iOwner] == 1 && is_valid_ent(iStored))
            {
               entity_set_int(iStored, EV_INT_WEAPONKEY, GOLDENM3_WEAPONKEY);
               g_Golden[M3][iOwner] = 0;
               entity_set_model(entity, g_Gold[M3][W_MODEL]);

               return FMRES_SUPERCEDE;
            }
         }
         case '4':
         {
            iStored = fm_find_ent_by_owner(ENG_NULLENT, weapons_name[M4A1], entity);

            if(g_Golden[M4A1][iOwner] == 1 && is_valid_ent(iStored))
            {
               entity_set_int(iStored, EV_INT_WEAPONKEY, GOLDENM4A1_WEAPONKEY);
               g_Golden[M4A1][iOwner] = 0;
               entity_set_model(entity, g_Gold[M4A1][W_MODEL]);

               return FMRES_SUPERCEDE;
            }
         }
         case 'p':
         {
            iStored = fm_find_ent_by_owner(ENG_NULLENT, weapons_name[MP5NAVY], entity);

            if(g_Golden[MP5NAVY][iOwner] == 1 && is_valid_ent(iStored))
            {
               entity_set_int(iStored, EV_INT_WEAPONKEY, GOLDENMP5NAVY_WEAPONKEY);
               g_Golden[MP5NAVY][iOwner] = 0;
               entity_set_model(entity, g_Gold[MP5NAVY][W_MODEL]);

               return FMRES_SUPERCEDE;
            }
         }
      }
   }
}

return FMRES_IGNORED;
}

public fw_CmdStart(id, uc_handle, seed)
{
if(!is_user_alive(id))
   return PLUGIN_HANDLED;

if((get_uc(uc_handle, UC_Buttons) & IN_ATTACK2) && !(pev(id, pev_oldbuttons) & IN_ATTACK2))
{
   if(floatround(CheckVipWeapons(id, 3)))
   {
      new i;
      for(i = 0; i < 5; i++)
      {
         switch(g_GoldenZoom[i][id])
         {
            case 1:
            {
               g_GoldenZoom[i][id] = 0;
               cs_set_user_zoom(id, CS_RESET_ZOOM, 0);
            }

            case 0:
            {
               g_GoldenZoom[i][id] = 1
               cs_set_user_zoom(id, CS_SET_AUGSG552_ZOOM, 0);
               emit_sound(id, CHAN_ITEM, "weapons/zoom.wav", 0.20, 2.40, 0, 100);
            }
         }
      }
   }

   return PLUGIN_CONTINUE;
}

return PLUGIN_HANDLED;
}

public ShowVipMenu(id)
{
if(!is_user_connected(id))
   return PLUGIN_HANDLED;

if(!is_user_vip(id))
{
   ColorChat(id, "!4%s!1 Imi pare rau. Nu ai acces la meniul pentru!3 membrii VIP!1.", tag);
   ColorChat(id, "!4%s!1 Poti cumpara VIP, contactand adresa Y!M:!3 %s!1.", tag, contact);
   return PLUGIN_HANDLED;
}
if(!is_user_alive(id))
{
   ColorChat(id, "!4%s!1 Ai acces la meniu doar daca esti in!3 viata!1.", tag);
   return PLUGIN_HANDLED;
}
if(count_vm[id] >= count)
{
   ColorChat(id, "!4%s!1 Ai folosit meniul runda asta. Asteapta pana runda viitoare.", tag);
   return PLUGIN_HANDLED;
}

VipMenu(id);
count_vm[id]++;
return PLUGIN_CONTINUE;
}

public VipMenu(id)
{
formatex(text_menu, charsmax(text_menu), "\wVIP Menu (GOLDEN)^n\y%s", g_HostName);
menu = menu_create(text_menu, "VipMenuHandler");
menu_callback = menu_makecallback("CallBackVipMenu");

formatex(text_items[0], charsmax(text_items[]), "%sGolden AK-47", on[0] ? "" : "\d");
menu_additem(menu, text_items[0], "1", 0, menu_callback);

formatex(text_items[1], charsmax(text_items[]), "%sGolden M4A1", on[1] ? "" : "\d");
menu_additem(menu, text_items[1], "2", 0, menu_callback);

formatex(text_items[2], charsmax(text_items[]), "%sGolden AWP", on[2] ? "" : "\d");
menu_additem(menu, text_items[2], "3", 0, menu_callback);

formatex(text_items[3], charsmax(text_items[]), "%sGolden M3", on[3] ? "" : "\d");
menu_additem(menu, text_items[3], "4", 0, menu_callback);

formatex(text_items[4], charsmax(text_items[]), "%sGolden Mp5Navy", on[4] ? "" : "\d");
menu_additem(menu, text_items[4], "5", 0, menu_callback);

menu_setprop(menu, MPROP_EXIT, MEXIT_ALL);
menu_display(id, menu, 0);

return PLUGIN_CONTINUE;
}

public VipMenuHandler(id, menu, item)
{
if(!is_user_connected(id))
{
   menu_destroy(menu);
   return PLUGIN_HANDLED;
}
if(!is_user_vip(id))
{
   ColorChat(id, "!4%s!1 Imi pare rau. Nu ai acces la meniul pentru!3 membrii VIP!1.", tag);
   ColorChat(id, "!4%s!1 Poti cumpara VIP, contactand adresa Y!M:!3 %s!1.", tag, contact);
   menu_destroy(menu);
   return PLUGIN_HANDLED;
}

new data[6], name[64], access, CallBack;
menu_item_getinfo(menu, item, access, data, charsmax(data), name, charsmax(name), CallBack);
new key = str_to_num(data);

switch(key)
{
   case 1:
   {
      bacon_strip_weapon(id, "weapon_ak47");
      g_Golden[AK47][id] = 1;
      give_item(id, "weapon_ak47");

      if(!unlimited_clip[AK47])
         cs_set_user_bpammo(id, CSW_AK47, 120);

      ColorChat(id, "!4%s!1 Ai ales!3 Golden AK-47!1.", tag);
      ColorChat(id, "!4%s!1 Damage: x!3%1.2f!4 |!1 No recoil:!3 %1.2f!4 |!1 Throw Speed:!3 %1.2f!4 |!1 Unlimited Clip:!3 %s!4 |!1 Gold Bullets:!3 %s", tag, multi_dmg[0], no_recoil[0], throw_speed[0], unlimited_clip[AK47] == 1 ? "on" : "off", gold_bullets[AK47] == 1 ? "on" : "off");
   }

   case 2:
   {
      bacon_strip_weapon(id, "weapon_m4a1");
      g_Golden[M4A1][id] = 1;
      give_item(id, "weapon_m4a1");

      if(!unlimited_clip[M4A1])
         cs_set_user_bpammo(id, CSW_M4A1, 120);

      ColorChat(id, "!4%s!1 Ai ales!3 Golden M4A1!1.", tag);
      ColorChat(id, "!4%s!1 Damage: x!3%1.2f!4 |!1 No recoil:!3 %1.2f!4 |!1 Throw Speed:!3 %1.2f!4 |!1 Unlimited Clip:!3 %s!4 |!1 Gold Bullets:!3 %s", tag, multi_dmg[1], no_recoil[1], throw_speed[1], unlimited_clip[M4A1] == 1 ? "on" : "off", gold_bullets[M4A1] == 1 ? "on" : "off");
   }

   case 3:
   {
      bacon_strip_weapon(id, "weapon_awp");
      g_Golden[AWP][id] = 1;
      give_item(id, "weapon_awp");

      if(!unlimited_clip[AWP])
         cs_set_user_bpammo(id, CSW_AWP, 30);

      ColorChat(id, "!4%s!1 Ai ales!3 Golden AWP!1.", tag);
      ColorChat(id, "!4%s!1 Damage: x!3%1.2f!4 |!1 No recoil:!3 %1.2f!4 |!1 Throw Speed:!3 %1.2f!4 |!1 Unlimited Clip:!3 %s!4 |!1 Gold Bullets:!3 %s", tag, multi_dmg[2], no_recoil[2], throw_speed[2], unlimited_clip[AWP] == 1 ? "on" : "off", gold_bullets[AWP] == 1 ? "on" : "off");
   }

   case 4:
   {
      bacon_strip_weapon(id, "weapon_m3");
      g_Golden[M3][id] = 1;
      give_item(id, "weapon_m3");

      if(!unlimited_clip[M3])
         cs_set_user_bpammo(id, CSW_M3, 32);

      ColorChat(id, "!4%s!1 Ai ales!3 Golden M3!1.", tag);
      ColorChat(id, "!4%s!1 Damage: x!3%1.2f!4 |!1 No recoil:!3 %1.2f!4 |!1 Throw Speed:!3 %1.2f!4 |!1 Unlimited Clip:!3 %s!4 |!1 Gold Bullets:!3 %s", tag, multi_dmg[3], no_recoil[3], throw_speed[3], unlimited_clip[M3] == 1 ? "on" : "off", gold_bullets[M3] == 1 ? "on" : "off");
   }

   case 5:
   {
      bacon_strip_weapon(id, "weapon_mp5navy");
      g_Golden[MP5NAVY][id] = 1;
      give_item(id, "weapon_mp5navy");

      if(!unlimited_clip[MP5NAVY])
         cs_set_user_bpammo(id, CSW_MP5NAVY, 120);

      ColorChat(id, "!4%s!1 Ai ales!3 Golden Mp5NavyP!1.", tag);
      ColorChat(id, "!4%s!1 Damage: x!3%1.2f!4 |!1 No recoil:!3 %1.2f!4 |!1 Throw Speed:!3 %1.2f!4 |!1 Unlimited Clip:!3 %s!4 |!1 Gold Bullets:!3 %s", tag, multi_dmg[4], no_recoil[4], throw_speed[4], unlimited_clip[MP5NAVY] == 1 ? "on" : "off", gold_bullets[MP5NAVY] == 1 ? "on" : "off");
   }
}

menu_destroy(menu);
return PLUGIN_HANDLED;
}

public CallBackVipMenu(id, menu, item)
{
new data[6], name[64], access, CallBack;
menu_item_getinfo(menu, item, access, data, charsmax(data), name, charsmax(name), CallBack);

switch(data[0])
{
   case '1':
   {
      if(on[0] == 0 || g_Golden[AK47][id] == 1)
         return ITEM_DISABLED;
   }
   case '2':
   {
      if(on[1] == 0 || g_Golden[M4A1][id] == 1)
         return ITEM_DISABLED;
   }
   case '3':
   {
      if(on[2] == 0 || g_Golden[AWP][id] == 1)
         return ITEM_DISABLED;
   }
   case '4':
   {
      if(on[3] == 0 || g_Golden[M3][id] == 1)
         return ITEM_DISABLED;
   }
   case '5':
   {
      if(on[4] == 0 || g_Golden[MP5NAVY][id] == 1)
         return ITEM_DISABLED;
   }
}

return ITEM_ENABLED;
}

stock Float:CheckVipWeapons(const id, number)
{
new Float:fValue;
switch(get_user_weapon(id))
{
   case CSW_AK47:
   {
      if(g_Golden[AK47][id])
      {
         switch(number)
         {
            case 0: fValue = multi_dmg[0];
            case 1: fValue = no_recoil[0];
            case 2: fValue = throw_speed[0];
            case 3: fValue = float(zoom[0]);
         }
      }
   }
   case CSW_M4A1:
   {
      if(g_Golden[M4A1][id])
      {
         switch(number)
         {
            case 0: fValue = multi_dmg[1];
            case 1: fValue = no_recoil[1];
            case 2: fValue = throw_speed[1];
            case 3: fValue = float(zoom[1]);
         }
      }
   }
   case CSW_AWP:
   {
      if(g_Golden[AWP][id])
      {
         switch(number)
         {
            case 0: fValue = multi_dmg[2];
            case 1: fValue = no_recoil[2];
            case 2: fValue = throw_speed[2];
            case 3: fValue = float(zoom[2]);
         }
      }
   }
   case CSW_M3:
   {
      if(g_Golden[M3][id])
      {
         switch(number)
         {
            case 0: fValue = multi_dmg[3];
            case 1: fValue = no_recoil[3];
            case 2: fValue = throw_speed[3];
            case 3: fValue = float(zoom[3]);
         }
      }
   }
   case CSW_MP5NAVY:
   {
      if(g_Golden[MP5NAVY][id])
      {
         switch(number)
         {
            case 0: fValue = multi_dmg[4];
            case 1: fValue = no_recoil[4];
            case 2: fValue = throw_speed[4];
            case 3: fValue = float(zoom[4]);
         }
      }
   }
}

return fValue;
}

load_customization_from_files()
{
// Build customization file path
new path[64];
get_configsdir(path, charsmax(path));
format(path, charsmax(path), "%s/vip_configurations.ini", path);

// File not present
if(!file_exists(path))
{
   new error[100];
   formatex(error, charsmax(error), "Cannot load customization file %s!", path);
   set_fail_state(error);
   return;
}

// Set up some vars to hold parsing info
new linedata[1024], key[64], value[960], section = SECTION_NONE;

// Open customization file for reading
new file = fopen(path, "rt");

while(file && !feof(file))
{
   // Read one line at a time
   fgets(file, linedata, charsmax(linedata));

   // Replace newlines with a null character to prevent headaches
   replace(linedata, charsmax(linedata), "^n^n", "");

   // Blank line or comment
   if(!linedata[0] || linedata[0] == ';')
      continue;

   // New section starting
   if(linedata[0] == '[')
   {
      section++;
      continue;
   }

   // Get key and value(s)
   strtok(linedata, key, charsmax(key), value, charsmax(value), '=');

   // Trim spaces
   trim(key);
   trim(value);

   switch(section)
   {
      case SECTION_GOLDENAK47:
      {
         if(equal(key, "ON GOLDEN AK-47"))
            on[0] = clamp(str_to_num(value), 0, 1);
         else if(equal(key, "V MODEL"))
         {
            while(value[0] != 0 && strtok(value, key, charsmax(key), value, charsmax(value), ','))
            {
               trim(key);
               trim(value);

               copy(g_Gold[AK47][V_MODEL], charsmax(g_Gold[]), key);
            }
            precache_model(g_Gold[AK47][V_MODEL]);
         }
         else if(equal(key, "P MODEL"))
         {
            while(value[0] != 0 && strtok(value, key, charsmax(key), value, charsmax(value), ','))
            {
               trim(key);
               trim(value);

               copy(g_Gold[AK47][P_MODEL], charsmax(g_Gold[]), key);
            }
            precache_model(g_Gold[AK47][P_MODEL]);
         }
         else if(equal(key, "W MODEL"))
         {
            while(value[0] != 0 && strtok(value, key, charsmax(key), value, charsmax(value), ','))
            {
               trim(key);
               trim(value);

               copy(g_Gold[AK47][W_MODEL], charsmax(g_Gold[]), key);
            }
            precache_model(g_Gold[AK47][W_MODEL]);
         }
         else if(equal(key, "MULTI DMG"))
            multi_dmg[0] = floatclamp(floatstr(value), 1.0, 2.0);
         else if(equal(key, "NO RECOIL"))
            no_recoil[0] = floatclamp(floatstr(value), 0.0, 1.0);
         else if(equal(key, "THROW SPEED"))
            throw_speed[0] = floatclamp(floatstr(value), 0.0, 2.0);
         else if(equal(key, "UNLIMITED CLIP"))
            unlimited_clip[0] = clamp(str_to_num(value), 0, 1);
         else if(equal(key, "GOLD BULLETS"))
            gold_bullets[0] = clamp(str_to_num(value), 0, 1);
         else if(equal(key, "ZOOM"))
            zoom[0] = clamp(str_to_num(value), 0, 1);
      }

      case SECTION_GOLDENM4A1:
      {
         if(equal(key, "ON GOLDEN M4A1"))
            on[1] = clamp(str_to_num(value), 0, 1);
         else if(equal(key, "V MODEL"))
         {
            while(value[0] != 0 && strtok(value, key, charsmax(key), value, charsmax(value), ','))
            {
               trim(key);
               trim(value);

               copy(g_Gold[M4A1][V_MODEL], charsmax(g_Gold[]), key);
            }
            precache_model(g_Gold[M4A1][V_MODEL]);
         }
         else if(equal(key, "P MODEL"))
         {
            while(value[0] != 0 && strtok(value, key, charsmax(key), value, charsmax(value), ','))
            {
               trim(key);
               trim(value);

               copy(g_Gold[M4A1][P_MODEL], charsmax(g_Gold[]), key);
            }
            precache_model(g_Gold[M4A1][P_MODEL]);
         }
         else if(equal(key, "W MODEL"))
         {
            while(value[0] != 0 && strtok(value, key, charsmax(key), value, charsmax(value), ','))
            {
               trim(key);
               trim(value);

               copy(g_Gold[M4A1][W_MODEL], charsmax(g_Gold[]), key);
            }
            precache_model(g_Gold[M4A1][W_MODEL]);
         }
         else if(equal(key, "MULTI DMG"))
            multi_dmg[1] = floatclamp(floatstr(value), 1.0, 2.0);
         else if(equal(key, "NO RECOIL"))
            no_recoil[1] = floatclamp(floatstr(value), 0.0, 1.0);
         else if(equal(key, "THROW SPEED"))
            throw_speed[1] = floatclamp(floatstr(value), 0.0, 2.0);
         else if(equal(key, "UNLIMITED CLIP"))
            unlimited_clip[1] = clamp(str_to_num(value), 0, 1);
         else if(equal(key, "GOLD BULLETS"))
            gold_bullets[1] = clamp(str_to_num(value), 0, 1);
         else if(equal(key, "ZOOM"))
            zoom[1] = clamp(str_to_num(value), 0, 1);
      }
      case SECTION_GOLDENAWP:
      {
         if(equal(key, "ON GOLDEN AWP"))
            on[2] = clamp(str_to_num(value), 0, 1);
         else if(equal(key, "V MODEL"))
         {
            while(value[0] != 0 && strtok(value, key, charsmax(key), value, charsmax(value), ','))
            {
               trim(key);
               trim(value);

               copy(g_Gold[AWP][V_MODEL], charsmax(g_Gold[]), key);
            }
            precache_model(g_Gold[AWP][V_MODEL]);
         }
         else if(equal(key, "P MODEL"))
         {
            while(value[0] != 0 && strtok(value, key, charsmax(key), value, charsmax(value), ','))
            {
               trim(key);
               trim(value);

               copy(g_Gold[AWP][P_MODEL], charsmax(g_Gold[]), key);
            }
            precache_model(g_Gold[AWP][P_MODEL]);
         }
         else if(equal(key, "W MODEL"))
         {
            while(value[0] != 0 && strtok(value, key, charsmax(key), value, charsmax(value), ','))
            {
               trim(key);
               trim(value);

               copy(g_Gold[AWP][W_MODEL], charsmax(g_Gold[]), key);
            }
            precache_model(g_Gold[AWP][W_MODEL]);
         }
         else if(equal(key, "MULTI DMG"))
            multi_dmg[2] = floatclamp(floatstr(value), 1.0, 2.0);
         else if(equal(key, "NO RECOIL"))
            no_recoil[2] = floatclamp(floatstr(value), 0.0, 1.0);
         else if(equal(key, "THROW SPEED"))
            throw_speed[2] = floatclamp(floatstr(value), 0.0, 2.0);
         else if(equal(key, "UNLIMITED CLIP"))
            unlimited_clip[2] = clamp(str_to_num(value), 0, 1);
         else if(equal(key, "GOLD BULLETS"))
            gold_bullets[2] = clamp(str_to_num(value), 0, 1);
         else if(equal(key, "ZOOM"))
            zoom[2] = clamp(str_to_num(value), 0, 1);
      }
      case SECTION_GOLDENM3:
      {
         if(equal(key, "ON GOLDEN M3"))
            on[3] = clamp(str_to_num(value), 0, 1);
         else if(equal(key, "V MODEL"))
         {
            while(value[0] != 0 && strtok(value, key, charsmax(key), value, charsmax(value), ','))
            {
               trim(key);
               trim(value);

               copy(g_Gold[M3][V_MODEL], charsmax(g_Gold[]), key);
            }
            precache_model(g_Gold[M3][V_MODEL]);
         }
         else if(equal(key, "P MODEL"))
         {
            while(value[0] != 0 && strtok(value, key, charsmax(key), value, charsmax(value), ','))
            {
               trim(key);
               trim(value);

               copy(g_Gold[M3][P_MODEL], charsmax(g_Gold[]), key);
            }
            precache_model(g_Gold[M3][P_MODEL]);
         }
         else if(equal(key, "W MODEL"))
         {
            while(value[0] != 0 && strtok(value, key, charsmax(key), value, charsmax(value), ','))
            {
               trim(key);
               trim(value);

               copy(g_Gold[M3][W_MODEL], charsmax(g_Gold[]), key);
            }
            precache_model(g_Gold[M3][W_MODEL]);
         }
         else if(equal(key, "MULTI DMG"))
            multi_dmg[3] = floatclamp(floatstr(value), 1.0, 2.0);
         else if(equal(key, "NO RECOIL"))
            no_recoil[3] = floatclamp(floatstr(value), 0.0, 1.0);
         else if(equal(key, "THROW SPEED"))
            throw_speed[3] = floatclamp(floatstr(value), 0.0, 2.0);
         else if(equal(key, "UNLIMITED CLIP"))
            unlimited_clip[3] = clamp(str_to_num(value), 0, 1);
         else if(equal(key, "GOLD BULLETS"))
            gold_bullets[3] = clamp(str_to_num(value), 0, 1);
         else if(equal(key, "ZOOM"))
            zoom[3] = clamp(str_to_num(value), 0, 1);
      }
      case SECTION_GOLDENMP5:
      {
         if(equal(key, "ON GOLDEN MP5NAVY"))
            on[4] = clamp(str_to_num(value), 0, 1);
         else if(equal(key, "V MODEL"))
         {
            while(value[0] != 0 && strtok(value, key, charsmax(key), value, charsmax(value), ','))
            {
               trim(key);
               trim(value);

               copy(g_Gold[MP5NAVY][V_MODEL], charsmax(g_Gold[]), key);
            }
            precache_model(g_Gold[MP5NAVY][V_MODEL]);
         }
         else if(equal(key, "P MODEL"))
         {
            while(value[0] != 0 && strtok(value, key, charsmax(key), value, charsmax(value), ','))
            {
               trim(key);
               trim(value);

               copy(g_Gold[MP5NAVY][P_MODEL], charsmax(g_Gold[]), key);
            }
            precache_model(g_Gold[MP5NAVY][P_MODEL]);
         }
         else if(equal(key, "W MODEL"))
         {
            while(value[0] != 0 && strtok(value, key, charsmax(key), value, charsmax(value), ','))
            {
               trim(key);
               trim(value);

               copy(g_Gold[MP5NAVY][W_MODEL], charsmax(g_Gold[]), key);
            }
            precache_model(g_Gold[MP5NAVY][W_MODEL]);
         }
         else if(equal(key, "MULTI DMG"))
            multi_dmg[4] = floatclamp(floatstr(value), 1.0, 2.0);
         else if(equal(key, "NO RECOIL"))
            no_recoil[4] = floatclamp(floatstr(value), 0.0, 1.0);
         else if(equal(key, "THROW SPEED"))
            throw_speed[4] = floatclamp(floatstr(value), 0.0, 2.0);
         else if(equal(key, "UNLIMITED CLIP"))
            unlimited_clip[4] = clamp(str_to_num(value), 0, 1);
         else if(equal(key, "GOLD BULLETS"))
            gold_bullets[4] = clamp(str_to_num(value), 0, 1);
         else if(equal(key, "ZOOM"))
            zoom[4] = clamp(str_to_num(value), 0, 1);
      }
   }
}
if(file) fclose(file);
}

stock bacon_strip_weapon(index, weapon[])
{
if(!equal(weapon, "weapon_", 7))
   return PLUGIN_CONTINUE;

static weaponid;
weaponid = get_weaponid(weapon)

if(!weaponid)
   return PLUGIN_CONTINUE;

static weaponent;
weaponent = fm_find_ent_by_owner(-1, weapon, index);

if(!weaponent)
   return PLUGIN_CONTINUE;

if(get_user_weapon(index) == weaponid)
   ExecuteHamB(Ham_Weapon_RetireWeapon, weaponent);

if(!ExecuteHamB(Ham_RemovePlayerItem, index, weaponent))
   return PLUGIN_CONTINUE;

ExecuteHamB(Ham_Item_Kill, weaponent);
set_pev(index, pev_weapons, pev(index, pev_weapons) & ~(1<<weaponid));

return PLUGIN_HANDLED;
}

stock fm_find_ent_by_owner(id, const szClassName[], iOwner, jghgtype = 0)
{
new str_type[11] = "classname", iEnt = id;

switch(jghgtype)
{
   case 1: str_type = "target";
   case 2: str_type = "targetname";
}

while((iEnt = engfunc(EngFunc_FindEntityByString, iEnt, str_type, szClassName)) && pev(iEnt, pev_owner) != iOwner) {}
return iEnt;
}

stock ColorChat(id, String[], any:...)
{
static szMesage[192];
vformat(szMesage, charsmax(szMesage), String, 3);

replace_all(szMesage, charsmax(szMesage), "!1", "^1");
replace_all(szMesage, charsmax(szMesage), "!3", "^3");
replace_all(szMesage, charsmax(szMesage), "!4", "^4");

static g_msg_SayText = 0;
if(!g_msg_SayText)
   g_msg_SayText = get_user_msgid("SayText");

new Players[32], iNum = 1, i;

if(id) Players[0] = id;
else get_players(Players, iNum, "ch");

for(--iNum; iNum >= 0; iNum--)
{
   i = Players[iNum];

   message_begin(MSG_ONE_UNRELIABLE, g_msg_SayText, _, i);
   write_byte(i);
   write_string(szMesage);
   message_end();
}
}

In loc de P90 ai mp5navy.
Codul este extras dintr-un pljuginul de-al meu.
Ca sa ruleze cum trebe pluginul ai nevoie de vip_configurations.ini.
Il ai aici mai jos.

Spoiler:

In sursa completezi cum vrei: (cauti liniilea astea la inceput)

Code:

#define count 4 // de cate ori poti accesa meniul pe runda
new const tag[] = "[VIP GOLD]"; // tagul care apara in chat (prefix)
new const contact[] = "[email protected]"; // cei care nu au vip, le va aparea un mesaj informativ cum pot achizitiona VIP

comanda este /vipgold

Staff message (-P!C@-):

Termina cu flame-ul, te-am mai avertizat odata!

VAND / MODIFIC / CREEZ [AMXX]

Creez orice plugin LEVEL MOD pentru orice MOD de CS.
Contact: sef_yontu

Sa[q] · Posted: 05-08-2015, 13:15:00 | Translate post to: ... (Click for more languages)

Pune te rog sma si amx

destroi112 · Posted: 07-08-2015, 22:46:12 | Translate post to: ... (Click for more languages)

Compilezi aici -> https://amx.freakz.ro/

Retired from Amxmodx