modificare plugin

DiaNNa ;x · Posted: 11-04-2010, 11:56:30 | Translate post to: ... (Click for more languages)

cine ar putea sa imi modifice si mie pluginu aici sma
sa fie ca un fel de bhop_detector.amxx,sa nu mai dea atatea erori,ca eu personal mi-am prins urechile....

Tyger · Posted: 11-04-2010, 12:06:45 | Translate post to: ... (Click for more languages)

ai incercat hack_hunter?

Edited: Fara reclama in semnatura

ShiTeNN · Posted: 11-04-2010, 13:25:50 | Translate post to: ... (Click for more languages)

hack_hunter ARE NISTE BUGURI SI DACA NU E BN CONFIGURAT NU AI CE FC CU EL

[dm.freakz.ro] Se cauta admini capabili

DiaNNa ;x · Posted: 11-04-2010, 13:27:29 | Translate post to: ... (Click for more languages)

dupa cum zice,si oricum nu deteacteaza no recoil,aer buguri

am facut proba

ShiTeNN · Posted: 11-04-2010, 14:16:00 | Translate post to: ... (Click for more languages)

Exact:)) pluginul ala e facut ca sa fie. vezi ca e un plugin pentru DethRun care dedecteaza bhopu din cfg. dar mai exact u ce vrei?!l

[dm.freakz.ro] Se cauta admini capabili

Hy2RoGeN · Last edited by Hy2RoGeN on 11-04-2010, 17:16:34; edited 1 time in total

uita-te aici
L.E: np

a durat 1 minute sa caut.

DiaNNa ;x · Posted: 11-04-2010, 16:50:25 | Translate post to: ... (Click for more languages)

multumsc

asta il cautam aleluia
Edit:Este plugin respins,nu a fost acceptat...si i-am facut proba nu merge

revox · Posted: 12-04-2010, 22:23:39 | Translate post to: ... (Click for more languages)

na

Code:

#include <amxmodx>
#include <fakemeta>

enum
{
TYPE_JUMP,
TYPE_DUCK,

g_iMaxTypes
};

enum
{
LOOP_SPECIAL,
LOOP_AUTOBUY,
LOOP_REBUY,

g_iMaxLoops
};

new g_iDetected[33][g_iMaxTypes];

const g_iCmdChars = 20;

new const g_sPunishments[][] =
{
"",
"slay",
"kick",
"bann"
};
new const g_iScriptKeys[g_iMaxTypes] =
{
IN_JUMP,
IN_DUCK
};
new const g_sScriptTypes[g_iMaxTypes][] =
{
"Bhop",
"Gstrafe"
};
new const g_sLoopTypes[g_iMaxLoops][] =
{
"special",
"autobuy",
"rebuy"
};
new const g_sLoopCodes[g_iMaxLoops][] =
{
"_special",
"cl_autobuy",
"cl_rebuy"
};
new const g_sLetters[26][] =
{
"a", "b", "c", "d", "e", "f", "g", "h", "i", "j", "k" ,"l", "m",
"n", "o", "p", "q", "r", "s", "t", "u", "v", "w", "x", "y", "z"
};

new gbsd_on[g_iMaxTypes];
new gbsd_punishment[g_iMaxTypes];
new gbsd_bantime[g_iMaxTypes];
new gbsd_bantype;
new gbsd_warntime;

new g_iMsgSayText;
new g_iMaxPlayers;

public plugin_init()
{
register_plugin("Gstrafe & Bhop Script Detector", "0.5", "Exolent");

register_forward(FM_PlayerPreThink, "fwd_FM_PlayerPreThink");

gbsd_on[TYPE_JUMP] =    register_cvar("gbsd_bhop_on", "1");
gbsd_punishment[TYPE_JUMP] = register_cvar("gbsd_bhop_punishment", "1");
gbsd_bantime[TYPE_JUMP] = register_cvar("gbsd_bhop_bantime", "5");
gbsd_on[TYPE_DUCK] =    register_cvar("gbsd_gstrafe_on", "1");
gbsd_punishment[TYPE_DUCK] = register_cvar("gbsd_gstrafe_punishment", "1");
gbsd_bantime[TYPE_DUCK] = register_cvar("gbsd_gstrafe_bantime", "5");
gbsd_bantype =       register_cvar("gbsd_bantype", "1");
gbsd_warntime =       register_cvar("gbsd_warntime", "60");

g_iMaxPlayers = get_maxplayers();
g_iMsgSayText = get_user_msgid("SayText");
}

public client_putinserver(id)
{
arrayset(g_iDetected[id], 0, g_iMaxTypes);

static Float:fWarnTime;
fWarnTime = get_pcvar_float(gbsd_warntime);
if(fWarnTime < 0.0)
{
   fWarnTime = 10.0;
   set_pcvar_float(gbsd_warntime, fWarnTime);
}
set_task(fWarnTime, "task_WarnPlayer", id);
}

public task_WarnPlayer(id)
{
static iOn[g_iMaxTypes];
iOn[TYPE_JUMP] = get_pcvar_num(gbsd_on[TYPE_JUMP]);
iOn[TYPE_DUCK] = get_pcvar_num(gbsd_on[TYPE_DUCK]);

if(iOn[TYPE_JUMP] && iOn[TYPE_DUCK])
{
   gbsd_print(id, "^x04[GBSD]^x03 Bhop and Gstrafe Scripts^x01 are not allowed!");
}
else if(iOn[TYPE_JUMP])
{
   gbsd_print(id, "^x04[GBSD]^x03 Bhop Scripts^x01 are not allowed!");
}
else if(iOn[TYPE_DUCK])
{
   gbsd_print(id, "^x04[GBSD]^x03 Gstrafe Scripts^x01 are not allowed!");
}
}

public client_disconnect(id)
{
if(task_exists(id))
{
   remove_task(id);
}
}

public fwd_FM_PlayerPreThink(id)
{
if(!is_user_alive(id))
{
   return FMRES_IGNORED;
}

static iOn[g_iMaxTypes];
iOn[TYPE_JUMP] = get_pcvar_num(gbsd_on[TYPE_JUMP]);
iOn[TYPE_DUCK] = get_pcvar_num(gbsd_on[TYPE_DUCK]);
if(!iOn[TYPE_JUMP] && !iOn[TYPE_DUCK])
{
   return FMRES_IGNORED;
}

static iButton[33], iOldButtons[33];
iButton[id] = pev(id, pev_button);
iOldButtons[id] = pev(id, pev_oldbuttons);

static sCommand[g_iMaxLoops][g_iCmdChars + 6];
static sArgument[g_iMaxLoops][g_iCmdChars + 6];
static const iLen = sizeof(sCommand[]) - 1;
static i, j, k;

for(i = 0; i < g_iMaxTypes; i++)
{
   if(iOn[i] && (iButton[id] & g_iScriptKeys[i]) && !(iOldButtons[id] & g_iScriptKeys[i]))
   {
      for(j = 0; j < g_iMaxLoops; j++)
      {
         formatex(sCommand[j], iLen, "gbsd_%c", g_sScriptTypes[i][0]);
         formatex(sArgument[j], iLen, "gbsd_%c", g_sLoopTypes[j][0]);
         for(k = strlen(sCommand[j]); k < g_iCmdChars; k++)
         {
            add(sCommand[j], iLen, g_sLetters[random(26)]);
            add(sArgument[j], iLen, g_sLetters[random(26)]);
         }
         client_cmd(id, ";alias ^"%s^" ^"%s %s^"", g_sLoopCodes[j], sCommand[j], sArgument[j]);
      }
      return FMRES_IGNORED;
   }
}
return FMRES_IGNORED;
}

public client_command(id)
{
if(!is_user_alive(id) || is_on_ground(id))
{
   return PLUGIN_CONTINUE;
}

static sCommand[16];
static const iCmdLen = sizeof(sCommand) - 1;
read_argv(0, sCommand, iCmdLen);

static i;

static sArg[8];
static const iArgLen = sizeof(sArg) - 1;
read_argv(1, sArg, iArgLen);

static j;
if(equali(sCommand, "gbsd_", 5))
{
   for(i = 0; i < g_iMaxTypes; i++)
   {
      if(g_sScriptTypes[i][0] == sCommand[5])
      {
         if(equali(sArg, "gbsd_", 5))
         {
            for(j = 0; j < g_iMaxLoops; j++)
            {
               if(g_sLoopTypes[j][0] == sArg[5])
               {
                  handle_punishment(id, i, j);
                  return PLUGIN_HANDLED;
               }
            }
         }
      }
   }
}
return PLUGIN_CONTINUE;
}

stock handle_punishment(id, iScriptType, iLoopType)
{
if(iLoopType != LOOP_SPECIAL && ++g_iDetected[id][iScriptType] < 3)
{
   gbsd_print(id, "^x04[GBSD]^x01 Do not use^x03 cl_%sbuy^x01 on this server!", iLoopType == LOOP_AUTOBUY ? "auto" : "re");
   console_print(id, "[GBSD] Do not use cl_%sbuy on this server!", iLoopType == LOOP_AUTOBUY ? "auto" : "re");
   return;
}

static sName[32];
get_user_name(id, sName, sizeof(sName) - 1);

static iPunishment;
iPunishment = get_pcvar_num(gbsd_punishment[iScriptType]);

if(1 <= iPunishment <= 3)
{
   gbsd_print(0, "^x04[GBSD]^x03 %s^x01 was %sed for using a^x03 %s Script.",\
      sName, g_sPunishments[iPunishment], g_sScriptTypes[iScriptType]);
}

switch(iPunishment)
{
   case 1:
   {
      user_kill(id);
   }
   case 2:
   {
      server_cmd("kick #%d ^"%s Script Detected (Loop:%s)^"", get_user_userid(id), g_sScriptTypes[iScriptType], g_sLoopTypes[iLoopType]);
   }
   case 3:
   {
      static iBanType;
      iBanType = get_pcvar_num(gbsd_bantype);

      static sInfo[64];
      if(iBanType == 1)
      {
         get_user_authid(id, sInfo, sizeof(sInfo) - 1);
      }
      else
      {
         get_user_ip(id, sInfo, sizeof(sInfo) - 1, 1);
         if(iBanType != 2)
         {
            set_pcvar_num(gbsd_bantype, 2);
         }
      }
      server_cmd("kick #%d ^"%s Script Detected (Loop:%s)^"; wait; %s %d ^"%s^"; wait; writei%c",\
         get_user_userid(id), g_sScriptTypes[iScriptType], g_sLoopTypes[iLoopType], get_pcvar_num(gbsd_bantime[iScriptType]), iBanType == 1 ? "banid" : "addip", sInfo, iBanType == 1 ? 'd' : 'p');
   }
   default:
   {
      if(iPunishment != 0)
      {
         set_pcvar_num(gbsd_punishment[iScriptType], 0);
      }

      gbsd_print(0, "^x04[GBSD]^x03 %s^x01 is using a^x03 %s Script. (Loop:%s)",\
         sName, g_sScriptTypes[iScriptType], g_sLoopTypes[iLoopType]);
   }
}
}

stock bool:is_on_ground(index)
{
static iFlags;
iFlags = pev(index, pev_flags);
return ((iFlags & FL_ONGROUND) || (iFlags & FL_PARTIALGROUND) || (iFlags & FL_CONVEYOR) || (iFlags & FL_INWATER) || (iFlags & FL_FLOAT));
}

stock gbsd_print(index, const sFmt[], any:...)
{
if(get_playersnum() < 1)
{
   return 0;
}

static sMessage[192];
static const iMsgLen = sizeof(sMessage) - 1;
vformat(sMessage, iMsgLen, sFmt, 3);

static id, MSG_type;
if(is_user_connected(index))
{
   id = index;
   MSG_type = MSG_ONE_UNRELIABLE;
}
else
{
   id = get_player();
   MSG_type = MSG_BROADCAST;
}

message_begin(MSG_type, g_iMsgSayText, _, id);
write_byte(id);
write_string(sMessage);
message_end();

return 1;
}

stock get_player()
{
static i;
for(i = 1; i <= g_iMaxPlayers; i++)
{
   if(is_user_connected(i))
   {
      return i;
   }
}
return 0;
}

DiaNNa ;x · Posted: 13-04-2010, 20:57:18 | Translate post to: ... (Click for more languages)

DiaNNa ;x wrote:

cine ar putea sa imi modifice si mie pluginu aici sma
sa fie ca un fel de bhop_detector.amxx,sa nu mai dea atatea erori,ca eu personal mi-am prins urechile....

nu caut pt bhop,doar pt no recoil